home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO076.dsk
/
INSTALL.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
3KB
|
81 lines
10 REM <CTRL-M><CTRL-M><CTRL-[><CTRL-O>[[[[[[[[[[[[[[[[[[[[[<CTRL-N><CTRL-X><CTRL-M>Menu Installer<CTRL-M>by Paul Lieberman<CTRL-M><CTRL-[><CTRL-O>[[[[[[[[[[[[[[[[[[[[[<CTRL-N><CTRL-X><CTRL-M><CTRL-M>
20 DIM NM$(20),PN$(20),PA$(20)
30 HOME :D$ = CHR$(4)
40 PRINT D$"PR#3": PRINT
50 P = 20
60 SP$ = "<CTRL-O> <CTRL-N>"
70 CM$ = "<CTRL-[><CTRL-O>C<CTRL-N><CTRL-X>"
80 AP$ = "<CTRL-[><CTRL-O>A<CTRL-N><CTRL-X>"
90 U$ = "<CTRL-[><CTRL-O>U<CTRL-N><CTRL-X>"
100 CR$ = "_"
110 BS$ = CHR$(8)
120 VTAB 2: HTAB 20: PRINT "<CTRL-O> Ramdisk file utility <CTRL-N>";
130 FOR V = 3 TO 7: VTAB V: HTAB 20: PRINT SP$SP$;: HTAB 59: PRINT SP$SP$;: NEXT
140 VTAB 8: HTAB 20: PRINT "<CTRL-O> Copyright 1989 OrchardWare Inc. <CTRL-N>";
150 VTAB 5: HTAB 32: PRINT "<CTRL-[><CTRL-O>[<CTRL-O><CTRL-N> Installer <CTRL-[><CTRL-O>[<CTRL-N><CTRL-X>";
160 VTAB 20: PRINT
170 VTAB 24: INVERSE : PRINT " Portions of Ramdisk Utilities copyright by Glen E. Bredon and Alan Bird ";
180 NORMAL
190 VTAB 20: PRINT
200 POKE 34,11: POKE 35,23
210 HOME
220 PRINT "Root Prefix of your ramdisk "U$" /";: GOSUB 670
230 PF$ = "/" +L$
240 PRINT
250 PRINT "Root Prefix of your startup disk "U$" /";: GOSUB 670
260 ST$ = "/" +L$
270 PRINT
280 PRINT "Path of the directory you want to copy to "PF$" "U$" /";: GOSUB 670
290 RD$ = "/" +L$
300 PRINT
310 PRINT "Ramdisk "U$" "PF$
320 PRINT "Startup disk "U$" "ST$
330 PRINT "Copy files from "U$" "RD$
340 PRINT : PRINT "Is this correct? (Y/n) ";
350 GET A$: PRINT A$
360 IF A$ = "N" OR A$ = "n" THEN 210
370 HOME
380 PRINT CM$" Installing your data.....";
390 L$ = "":A$ = ""
400 PRINT D$"STORE MENU.VAR"
410 PRINT "......";
420 PRINT D$"BLOAD INST.QUIT,A$2000"
430 POKE 8960, LEN(PF$)
440 FOR X = 1 TO LEN(PF$)
450 POKE 8960 +X, ASC( MID$ (PF$,X,1)) +128
460 NEXT
470 PRINT D$"BSAVE INST.QUIT,A$2000,L790"
480 Q$ = CHR$(34)
490 PRINT D$"OPEN PATCH"
500 PRINT D$"WRITE PATCH"
510 PRINT "LOAD RAMLOADER"
520 PRINT "70 RS$="Q$RD$Q$
530 PRINT "80 RD$="Q$PF$Q$
540 PRINT "SAVE RAMLOADER"
550 PRINT "RUN INSTALL,@600"
560 PRINT D$"CLOSE PATCH"
570 PRINT "......"
580 PRINT D$"EXEC PATCH"
590 END
600 HOME :D$ = CHR$(4)
610 PRINT "Installation complete! "
620 PRINT : PRINT "You should now copy the Ram Utility files to the proper directories."
630 PRINT : PRINT "Please refer to the Doc's."
640 PRINT D$"CLOSE PATCH"
650 PRINT D$"DELETE PATCH"
660 TEXT : END
670 L$ = ""
680 PRINT CR$BS$;
690 K = PEEK(49152): IF K <128 THEN 690
700 POKE 49168,0
710 K = K -128
720 IF K = 8 OR K = 127 THEN 790
730 IF K = 13 THEN PRINT " ": RETURN
740 IF K <65 AND LEN(L$) = 0 THEN 690
750 IF K <45 THEN 690
760 K$ = CHR$(K): PRINT K$;
770 L$ = L$ +K$
780 GOTO 680
790 IF LEN(L$) >0 THEN PRINT " "BS$BS$;
800 IF LEN(L$) >1 THEN L$ = LEFT$(L$, LEN(L$) -1): GOTO 680
810 GOTO 670